Editing Ranges

{{TipNew

|id=1611

|previous=1610

|next=1612

|created=2008

|complexity=basic

|author=

|version=7.0

|subpage=/200812

|category1=Usage

|category2=

}}

A ''range'' permits a command to be applied to a group of lines in the current buffer. For most commands, the default range is the current line. For example:

*<code>:s/old/new/g</code> &nbsp;&nbsp;changes all ''old'' to ''new'' in the current line

*<code>:11,15s/old/new/g</code> &nbsp;&nbsp;changes lines 11 to 15 inclusive

*<code>:%s/old/new/g</code> &nbsp;&nbsp;changes all lines

==Examples==

A range can be specified using line numbers or special characters, as in these examples:

{| class="wikitable"

!Range !! Description !! Example

|-

| <code>21</code> || line 21 || <code>:21s/old/new/g</code>

|-

| <code>1</code> || first line || <code>:1s/old/new/g</code>

|-

| <code>$</code> || last line || <code>:$s/old/new/g</code>

|-

| <code>.</code> || current line || <code>:.w single.txt</code>

|-

| <code>%</code> || all lines (same as <code>1,$</code>) || <code>:%s/old/new/g</code>

|-

| <code>21,25</code> || lines 21 to 25 inclusive || <code>:21,25s/old/new/g</code>

|-

| <code>21,$</code> || lines 21 to end || <code>:21,$s/old/new/g</code>

|-

| <code>.,$</code> || current line to end || <code>:.,$s/old/new/g</code>

|-

| <code>.+1,$</code> || line ''after'' current line to end || <code>:.+1,$s/old/new/g</code>

|-

| <code>.,.+5</code> || six lines (current to current+5 inclusive) || <code>:.,.+5s/old/new/g</code>

|-

| <code>.,.5</code> || same (<code>.5</code> is interpreted as <code>.+5</code>) || <code>:.,.5s/old/new/g</code>

|}

The <code>:s///</code> command substitutes in the specified lines. The <code>:w</code> command writes a file. On its own, <code>:w</code> writes all lines from the current buffer to the file name for the buffer. Given a range and a file name, <code>:w</code> writes only the specified lines to the specified file. The example above creates file <code>single.txt</code> containing the current line.

If you know you want to substitute in six lines, starting from the current line, you can use either of the ranges shown above. An easier method is to enter a count value (type <code>6</code>), then enter the colon command with no range (type <code>:s/old/new/g</code>). Because you entered a count, Vim displays the command:

<pre>

:.,.+5s/old/new/g

</pre>

==Default range==

For most commands, the default range is <code>.</code> (the current line, for example, <code>:s///</code> substitutes in the current line). However, for <code>:g//</code> and <code>:w</code> the default is <code>%</code> (all lines).

{| class="wikitable"

!Example !! Equivalent !! Description

|-

| <code>:s/old/new/g</code> || <code>:.s/old/new/g</code> || substitute in current line

|-

| <code>:g/old/</code> || <code>:%g/old/</code> || list all lines matching <code>old</code>

|-

| <code>:w my.txt</code> || <code>:%w my.txt</code> || write all lines to file <code>my.txt</code>

|}

==Selections==

A command like <code>:123,145s/old/new/g</code> substitutes in lines 123 to 145 inclusive, but what if you're not sure what the line numbers are? One method is to use ''marks'': Type <code>ma</code> in the first line, then type <code>mb</code> in the last line (to set marks <code>a</code> and <code>b</code>). Then enter command <code>:'a,'bs/old/new/g</code> to substitute in lines from mark <code>a</code> to <code>b</code>, inclusive.

Another method is to visually select lines, then enter a colon command (for example, <code>:s/old/new/g</code>). Note that you do not enter a range. However, because the command was entered while lines were selected, Vim displays the command as:

<pre>

:'<,'>s/old/new/g

</pre>

The range <code>'<,'></code> is entered automatically to identify the lines that were last visually selected (they do not need to be visually selected now).

For example, you might type <code>vip</code> to visually select "inner paragraph" (the paragraph holding the cursor). Then type <code>:s/old/new/g</code> to substitute in all lines in the selected paragraph.

==Deleting, copying and moving==

Ranges work with Ex commands (those typed after a colon, for example, <code>:w</code>). As well as the commands we've seen so far, it's handy to know how to use <code>:d</code> (delete lines), <code>:t</code> or <code>:co</code> (copy lines), and <code>:m</code> (move lines).

{| class="wikitable"

!Command !! Description

|-

| <code>:21,25d</code> || delete lines 21 to 25 inclusive

|-

| <code>:$d</code> || delete the last line

|-

| <code>:1,.-1d</code> || delete all lines before the current line

|-

| <code>:.+1,$d</code> || delete all lines after the current line

|-

| <code>:21,25t 30</code> || copy lines 21 to 25 inclusive to just after line 30

|-

| <code>:$t 0</code> || copy the last line to before the first line

|-

| <code>:21,25m 30</code> || move lines 21 to 25 inclusive to just after line 30

|-

| <code>:$m 0</code> || move the last line to before the first line

|}

The line numbers in a command are those ''before'' the command executes. In the earlier example which moved lines 21..25 to after 30, the "30" refers to the line number before the move occurred.

==Ranges with marks and searches==

In a range, a line number can be given as:

*A mark (for example, <code>'x</code> is the line containing mark <code>x</code>).

*A search (for example, <code>/pattern/</code> is the next line matching ''pattern'').

When using a mark, it must exist in the current buffer.

{| class="wikitable"

!Command !! Description

|-

| <code>:'a,'bd</code> || delete lines from mark <code>a</code> to mark <code>b</code>, inclusive

|-

| <code>:.,'bd</code> || delete lines from the current line to mark <code>b</code>, inclusive

|-

| <code>:'a,'bm 0</code> || move lines from mark <code>a</code> to <code>b</code> inclusive, to the beginning

|-

| <code>:'a,'bw file.txt</code> || write lines from mark <code>a</code> to <code>b</code> to file.txt

|-

| <code>:'a,'bw >> file.txt</code> || append lines from mark <code>a</code> to <code>b</code> to file.txt

|}

Here are some examples using searches:

;<code>:.,/green/co $</code>

:Copy the lines from the current line to the next line containing 'green' (inclusive), to the end of the buffer.

;<code>:/apples/,/apples/+1s/old/new/g</code>

:Replace all "old" in the next line in which the "apples" occurs, and the line following it.

;<code>:/apples/;.1s/old/new/g</code>

:Same (<code>.1</code> is <code>.+1</code>, and because <code>;</code> was used, the cursor position is set to the line matching "apples" ''before'' interpreting the <code>.+1</code>).

;<code>:/apples/,.100s/old/new/g</code>

:Replace all "old" in the next line in which "apples" occurs, and all lines up to and including 100 lines after the current line (where the command was entered).

To do a replace in blocks identified by an initial and a final pattern:

;<code>:/apples/,/peaches/ s/old/new/g</code>

:Replace all "old" in the first block that starts with "apples" and ends with "peaches".

:<code>/apples/</code> identifies the first line after the cursor containing "apples".

:<code>/peaches/</code> is similar (first line after the current line, ''not'' the first after "apples"). Be aware of backwards ranges.

:The block is all lines from "apples" to "peaches", inclusive.

;<code>:/apples/;/peaches/ s/old/new/g</code>

:Same, but "peaches" identifies the first occurrence ''after'' "apples".

;<code>:/apples/,/peaches/ s/^/# /g</code>

:Insert "<code># </code>" at the start of each line in the first block.

;<code>:/apples/+1,/peaches/-1 s/^/# /g</code>

:Insert "<code># </code>" at the start of each line inside the block.

To do a global replace in all blocks with the same patterns, [[Power of g|use <code>:g</code>]]:

;<code>:g/apples/,/peaches/ s/^/# /g</code>

:Insert "<code># </code>" at the start of each line in all identified blocks.

:<code>:g/apples/</code> identifies each line containing "apples".

:In each such line, <code>.,/peaches/ s/^/# /g</code> is executed

:(the <code>.</code> is assumed; it means the current line, where "apples" occurs).

;<code>:g/^function!\? \(s:\)\?My/;/^endfunction/s/^/" /</code>

:''This example is for a Vim script where functions start with <code>function</code> or <code>function!</code> and end with <code>endfunction</code>.''

:Insert "<code>" </code>" at the start of each line in each block.

:All functions that start with <code>function My</code> or <code>function s:My</code> will be commented out.

:The last line in each block is where <code>endfunction</code> first occurs (at the left margin), after where <code>function My</code> is found.

Even more tricks are available; see {{help|cmdline-ranges}}. Summary:

{| class="wikitable"

!Item !! Description

|-

| <code>/pattern/</code> || next line where ''pattern'' matches

|-

| <code>?pattern?</code> || previous line where ''pattern'' matches

|-

| <code>\/</code> || next line where the previously used search pattern matches

|-

| <code>\?</code> || previous line where the previously used search pattern matches

|-

| <code>\&</code> || next line where the previously used substitute pattern matches

|-

| <code>0;/that</code> || first line containing "that" (also matches in the first line)

|-

| <code>1;/that</code> || first line after line 1 containing "that"

|}

I find this counter-intuitive to define a range with commas. Examples : 21,25

I would prefer 21-25 ... --July 19, 2016

----

A dash cannot be used because it refers to negative numbers, relative to the current line. The following uses range <code>-3,-1</code> to yank (copy) the three line just before each line containing "password".

:let @a=''

:g/password/-3,-1y A

:new

:put a

[[User:JohnBeckett|JohnBeckett]] ([[User talk:JohnBeckett|talk]]) 00:05, July 30, 2016 (UTC)

----

Is there more documentation on the concept of "count value", as in this sentence from the wiki above:

"An easier method is to enter a count value (type 6), then enter the colon command with no range" ... ? --August 22, 2016

:See {{help|N:}} for "Count and Range". It has the example of <code>3:d<CR></code> being translated to <code>.,.+2d<CR></code>. [[User:JohnBeckett|JohnBeckett]] ([[User talk:JohnBeckett|talk]]) 06:04, August 23, 2016 (UTC)

----