Search and replace

{{TipImported
|id=31
|previous=30
|next=32
|created=2001
|complexity=basic
|author=
|version=6.0
|rating=1178/444
|category1=Searching
|category2=
}}
Vim provides the <code>:s</code> (substitute) command for search and replace; this tip shows examples of how to substitute. On some systems, gvim has ''Find and Replace'' on the Edit menu ({{help|:promptrepl}}), however it is easier to use the <code>:s</code> command due to its [[VimTip45|command line history]] and ability to insert text (for example, the word under the cursor) into the search or replace fields.

==Basic search and replace==
The <code>:substitute</code> command searches for a [[VimTip188|text pattern]], and replaces it with a text string. There are many options, but these are what you probably want:

;<code>:%s/foo/bar/g</code>
:Find each occurrence of 'foo' (in all lines), and replace it with 'bar'.

;<code>:s/foo/bar/g</code>
:Find each occurrence of 'foo' (in the current line only), and replace it with 'bar'.

;<code>:%s/foo/bar/gc</code>
:Change each 'foo' to 'bar', but ask for confirmation first.

;<code>:%s/\<foo\>/bar/gc</code>
:Change only whole words exactly matching 'foo' to 'bar'; ask for confirmation.

;<code>:%s/foo/bar/gci</code>
:Change each 'foo' (case insensitive due to the <code>i</code> flag) to 'bar'; ask for confirmation.
:<code>:%s/foo\c/bar/gc</code> is the same because <code>\c</code> makes the search case insensitive.
:This may be wanted after using <code>:set noignorecase</code> to make searches case sensitive (the default).

;<code>:%s/foo/bar/gcI</code>
:Change each 'foo' (case sensitive due to the <code>I</code> flag) to 'bar'; ask for confirmation.
:<code>:%s/foo\C/bar/gc</code> is the same because <code>\C</code> makes the search case sensitive.
:This may be wanted after using <code>:set ignorecase</code> to make searches case insensitive.

The <code>g</code> flag means ''global'' – each occurrence in the line is changed, rather than just the first. This tip assumes the default setting for the <code>'gdefault'</code> and <code>'edcompatible'</code> option (off), which requires that the <code>g</code> flag be included in <code>%s///g</code> to perform a global substitute. Using <code>:set gdefault</code> creates confusion because then <code>%s///</code> is global, whereas <code>%s///g</code> is not (that is, <code>g</code> reverses its meaning).

When using the <code>c</code> flag, you need to confirm for each match what to do. Vim will output something like:
<code>replace with foobar (y/n/a/q/l/^E/^Y)?</code>
(where foobar is the replacement part of the <code>:s/.../.../</code> command. You can type <code>y</code> which means to substitute this match, <code>n</code> to skip this match, <code>a</code> to substitute this and all remaining matches ("all" remaining matches), <code>q</code> to quit the command, <code>l</code> to substitute this match and quit (think of "last"), <code>^E</code> to scroll the screen up by holding the Ctrl key and pressing E and <code>^Y</code> to scroll the screen down by holding the Ctrl key and pressing Y. However, the last two choices are only available, if your Vim is a normal, big or huge built or the insert_expand feature was enabled at compile time (look for <code>+insert_expand</code> in the output of <code>:version</code>).

Also when using the <code>c</code> flag, Vim will jump to the first match it finds starting from the top of the buffer and prompt you for confirmation to perform replacement on that match.  Vim applies the <code>IncSearch</code> highlight group to the matched text to give you a visual cue as to which match it is operating on (set to <code>reverse</code> by default for all three term types as of Vim 7.3).  Additionally, if more than one match is found and you have search highlighting enabled with <code>:set hlsearch</code>, Vim highlights the remaining matches with the <code>Search</code> highlight group.  If you do use search highlighting, you should make sure that these two highlight groups are visually distinct or you won't be able to easily tell which match Vim is prompting you to substitute.

==Details==
'''Search range''':
{| class="cleartable" style="margin: 0 1em 1em 24px"
|style="vertical-align:top" |<code>:s/foo/bar/g</code> || Change each 'foo' to 'bar' in the current line.
|-
|style="vertical-align:top" |<code>:%s/foo/bar/g</code> || Change each 'foo' to 'bar' in all the lines.
|-
|style="vertical-align:top" |<code>:5,12s/foo/bar/g</code> || Change each 'foo' to 'bar' for all lines from line 5 to line 12 (inclusive).
|-
|style="vertical-align:top" |<code>:'a,'bs/foo/bar/g</code> || Change each 'foo' to 'bar' for all lines from mark a to mark b inclusive (see '''Note''' below).
|-
|style="vertical-align:top" |<code>:'<,'>s/foo/bar/g</code> || When compiled with <code>+visual</code>, change each 'foo' to 'bar' for all lines within a visual selection.  Vim automatically appends the visual selection range ('<,'>) for any ex command when you select an area and enter <code>:</code>.  Also, see '''Note''' below.
|-
|style="vertical-align:top" |<code>:.,$s/foo/bar/g</code> || Change each 'foo' to 'bar' for all lines from the current line (.) to the last line ($) inclusive.
|-
|style="vertical-align:top" |<code>:.,+2s/foo/bar/g</code> || Change each 'foo' to 'bar' for the current line (.) and the two next lines (+2).
|-
|style="vertical-align:top; white-space:nowrap;" | <code>:g/^baz/s/foo/bar/g</code> || Change each 'foo' to 'bar' in each line starting with 'baz'.
|}
:'''Note''': As of Vim 7.3, substitutions applied to a range defined by marks or a visual selection (which uses a special type of marks '< and '>) are not bounded by the column position of the marks by default.  Instead, Vim applies the substitution to the entire line on which each mark appears unless the <code>\%V</code> atom is used in the pattern like: <code>:'<,'>s/\%Vfoo/bar/g</code>.


'''When searching''':
:<code>.</code>, <code>*</code>, <code>\</code>, <code>[</code>, <code>^</code>, and <code>$</code> are metacharacters.
:<code>+</code>, <code>?</code>, <code>|</code>, <code>&</code>, <code>{</code>, <code>(</code>, and <code>)</code> must be escaped to use their special function.
:<code>\/</code> is / (use backslash + forward slash to search for forward slash)
:<code>\t</code> is tab, <code>\s</code> is whitespace
:<code>\n</code> is newline, <code>\r</code> is CR (carriage return = Ctrl-M = ^M)
:After an opening <code>[</code>, everything until the next closing <code>]</code> specifies a {{help|prefix=no|/collection}}. Character ranges can be represented with a <code>-</code>; for example a letter a, b, c, or the number 1 can be matched with <code>[1a-c]</code>. Negate the collection with <code>[^</code> instead of <code>[</code>; for example <code>[^1a-c]</code> matches any character except a, b, c, or 1.
:<code>\{#\}</code> is used for repetition. <code>/foo.\{2\}</code> will match foo and the two following characters. The <code>\</code> is not required on the closing <code>}</code> so <code>/foo.\{2}</code> will do the same thing.
:<code>\(foo\)</code> makes a backreference to foo. Parenthesis without escapes are literally matched. Here the <code>\</code> is required for the closing <code>\)</code>.

'''When replacing''':
:<code>\r</code> is newline, <code>\n</code> is a null byte (0x00).
:<code>\&</code> is ampersand (& is the text that matches the search pattern).
:<code>\0</code> inserts the text matched by the entire pattern
:<code>\1</code> inserts the text of the first backreference. <code>\2</code> inserts the second backreference, and so on.

You can use '''other delimiters''' with substitute:
:<code><nowiki>:s#http://www.example.com/index.html#http://example.com/#</nowiki></code>

Save typing by using <code>\zs</code> and <code>\ze</code> to set the '''start and end of a pattern'''. For example, instead of:
:<code>:s/Copyright 2007 All Rights Reserved/Copyright 2008 All Rights Reserved/</code>

Use:
:<code>:s/Copyright \zs2007\ze All Rights Reserved/2008/</code>

==Using the current word or registers==
{{anchor|substitute_last_search}}
;<code>:%s//bar/g</code>
:Replace each match of the last search pattern with 'bar'.
:For example, you might first place the cursor on the word <code>foo</code> then press <code>*</code> to search for that word.
:The above substitute would then change all words exactly matching 'foo' to 'bar'.

;<code>:%s/foo/<c-r><c-w>/g</code>
:Replace each occurrence of 'foo' with the word under the cursor.
:<code><c-r><c-w></code> means that you press Ctrl-R then Ctrl-W.
:The word under the cursor will be inserted as though you typed it.

;<code>:%s/foo/<c-r><c-a>/g</code>
:Replace each occurrence of 'foo' with the WORD under the cursor (delimited by whitespace).
:<code><c-r><c-a></code> means that you press Ctrl-R then Ctrl-A.
:The WORD under the cursor will be inserted as though you typed it.

;<code>:%s/foo/<c-r>a/g</code>
:Replace each occurrence of 'foo' with the contents of register 'a'.
:<code><c-r>a</code> means that you press Ctrl-R then <code>a</code>.
:The contents of register 'a' will be inserted as though you typed it.

;<code>:%s/foo/<c-r>0/g</code>
:Same as above, using register 0 which contains the text from the most recent yank command. Examples of yank (copy) commands are <code>yi(</code> which copies the text inside parentheses around the cursor, and <code>y$</code> which copies the text from the cursor to the end of the line. After a yank command which did not specify a destination register, the copied text can be entered by pressing Ctrl-R then <code>0</code>.

;<code>:%s/foo/\=@a/g</code>
:Replace each occurrence of 'foo' with the contents of register 'a'.
:<code>\=@a</code> is a reference to register 'a'.
:The contents of register 'a' is not shown in the command. This is useful if the register contains many lines of text.

;<code>:%s//<c-r>//g</code>
:Replace each match of the last search pattern with the <code>/</code> register (the last search pattern).
:After pressing Ctrl-R then <code>/</code> to insert the last search pattern (and before pressing Enter to perform the command), you could edit the text to make any required change.

;<code>:%s/<c-r>*/bar/g</code>
:Replace all occurrences of the text in the system clipboard (in the <code>*</code> register) with 'bar' (see next example if multiline).
:On some systems, selecting text (in Vim or another application) is all that is required to place that text in the <code>*</code> register.

;<code>:%s/<c-r>a/bar/g</code>
:Replace all occurrences of the text in register 'a' with 'bar'.
:<code><c-r>a</code> means that you press Ctrl-R then <code>a</code>. The contents of register 'a' will be inserted as though you typed it.
:Any newlines in register 'a' are inserted as <code>^M</code> and are not found.
:The search works if each <code>^M</code> is manually replaced with '\n' (two characters: backslash, 'n').
:This replacement can be performed while you type the command:
::<code>:%s/<c-r>=substitute(@a,"\n",'\\n','g')<CR>/bar/g</code>
:The <code>"\n"</code> (double quotes) represents the single character newline; the <code>'\\n'</code> (single quotes) represents two backslashes followed by '<code>n</code>'.
:The <code>substitute()</code> function is evaluated by the <code><c-r>=</code> (Ctrl-R <code>=</code>) expression register; it replaces each newline with a single backslash followed by '<code>n</code>'.
:The <code><CR></code> indicates that you press Enter to finish the <code>=</code> expression.

;<code>:%s/<c-r>0/bar/g</code>
:Same as above, using register 0 which contains the text from the most recent yank command.

See [[VimTip490|Paste registers in search or colon commands instead of using the clipboard]].

==Additional examples==
;<code>:%s/foo/bar/</code>
:On each line, replace the first occurrence of "foo" with "bar".

;<code>:%s/.*\zsfoo/bar/</code>
:On each line, replace the last occurrence of "foo" with "bar".

;<code>:%s/\<foo\>//g</code>
:On each line, delete all occurrences of the whole word "foo".

;<code>:%s/\<foo\>.*//</code>
:On each line, delete the whole word "foo" and all following text (to end of line).

;<code>:%s/\<foo\>.\{5}//</code>
:On each line, delete the first occurrence of the whole word "foo" and the following five characters.

;<code>:%s/\<foo\>\zs.*//</code>
:On each line, delete all text following the whole word "foo" (to end of line).

;<code>:%s/.*\<foo\>//</code>
:On each line, delete the whole word "foo" and all preceding text (from beginning of line).

;<code>:%s/.*\ze\<foo\>//</code>
:On each line, delete all the text preceding the whole word "foo" (from beginning of line).

;<code>:%s/.*\(\<foo\>\).*/\1/</code>
:On each line, delete all the text preceding and following the whole word "foo".

;<code>:%s/^\(\w\)/\u\1/</code>
:If the first character at the beginning of the current line is lowercase, switch it to uppercase using <code>\u</code> (see [[switching case of characters]]).

;<code>:%s/\(.*\n\)\{5\}/&\r/</code>
:Insert a blank line every 5 lines.
:The pattern searches for <code>\(.*\n\)</code> (any line including its line ending) repeated five times (<code>\{5\}</code>).
:The replacement is <code>&</code> (the text that was found), followed by <code>\r</code> (newline).

;<code>:%s/\<foo\(\a*\)\>/\=len(add(list, submatch(1)))?submatch(0):submatch(0)/g</code>
:Get a list of search results. (the list must exist)
:Sets the <code>modified</code> flag, because of the replacement, but the content is unchanged.
:'''Note''': With a recent enough Vim (version 7.3.627 or higher), you can simplify this to:
;<code>:%s/\<foo\(\a*\)\>/\=add(list, submatch(1))/gn</code>
:This has the advantage, that the buffer won't be marked modified and no extra undo state is created. The expression in the replacement part is executed in the sandbox and not allowed to modify the buffer.

==Special cases==
For substituting patterns with corresponding case-sensitive text, Michael Geddes's {{script|id=6|text=keepcase}} plugin can be used, e.g.:
;<code>:%SubstituteCase/\cHello/goodBye/g</code>
:Substitute 'Hello hello helLo HELLO' by 'Goodbye goodbye goodBye GOODBYE'

For changing the offsets in a patch file (line number of a block), this little snippet can be used:
;<code>s/^@@ -\(\d\+\),\(\d\+\) +\(\d\+\),\(\d\+\) @@$/\="@@ -".eval(submatch(1)+''offsetdiff'').",".submatch(2)." +".eval(submatch(3)+''offsetdiff'').",".submatch(4)." @@"/g</code>
Useful when we want to strip some blocks from a patch, without patch having to complain about offset differences.
:'''Note''' Should try to make the expression more compact, but don't know how without having the possibility of modifying unwanted lines.

==See also: using substitute==
*[[VimTip63|63 Applying substitutes to a visual block]]
*[[VimTip81|81 Substitute characters and lines easily]]
*[[VimTip159|159 Keystroke Saving Substituting and Searching]]
*[[VimTip406|406 Alternate delimiters for the replace command]]
*[[VimTip438|438 Search and replace in a visual selection]]
*[[VimTip464|464 Search and replace the word under the cursor]]
*[[VimTip479|479 Replace with no typing]]
*[[VimTip573|573 Repeating a substitute from current cursor position]]
*[[VimTip605|605 Replace a word with the yanked text]]
*[[VimTip654|654 Special characters in the substitute command]]
*[[VimTip755|755 Using an expression in substitute command]]
*[[VimTip808|808 Replace a visual-block of text with another such block]]
*[[VimTip915|915 Using g instead of substitute]]
*[[VimTip971|971 Substitute with incrementing numbers]]
*[[VimTip1114|1114 Step increment and replace]]
*[[VimTip1501|1501 Substitute last search]]

==See also: substitute in buffers/files==
*[[VimTip382|382 Search and replace in multiple buffers]]

==References==
*{{help|:substitute}}
*{{help|cmdline-ranges}}
*{{help|pattern}}
*{{help|'gdefault'}}
*{{help|registers}}

==Comments==
{{Todo}}
The large "see also" section may be useful to readers. We need to merge some of the related tips (but don't make the result too complex). I included the tip numbers to help editors keep track.

Want a short section mentioning that simple substitutes are often best handled by searching then manually changing (and pressing <code>.</code> to repeat the last change). Additionally, you can decide how to change each instance. See [[Copy or change search hit]] for a technique where you can press <code>n</code> to find the next instance, then type <code>cs</code> to change the search hit to whatever.